home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / plot_3dbox.pro < prev    next >
Text File  |  1997-07-08  |  9KB  |  258 lines
  1. ;  $Id: plot_3dbox.pro,v 1.4 1997/01/15 03:11:50 ali Exp $
  2. ;
  3. ; Copyright (c) 1994-1997, Research Systems, Inc.  All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5. ;+
  6. ; NAME:
  7. ;    Plot_3dbox
  8. ;
  9. ; PURPOSE:
  10. ;    This procedure plots data in a 3-dimensional box, with options
  11. ;    to have the data displayed on the walls surrounding the plot area.
  12. ;
  13. ; CATEGORY:
  14. ;    Plotting, Three-dimensional
  15. ;
  16. ; CALLING SEQUENCE:
  17. ;    Plot_3dbox, X, Y, Z
  18. ; 
  19. ; INPUTS:
  20. ;    X:    A one dimensional array that contains the X coordinats
  21. ;
  22. ;    Y:    A one dimensional array that contains the Y coordinates
  23. ;
  24. ;    Z:    A one dimensional array that contains the Z coordinates
  25. ;
  26. ; OPTIONAL INPUTS:
  27. ;    None.
  28. ;    
  29. ; KEYWORD PARAMETERS:
  30. ;    COLOR:        The color for the Grid and Lines or the Color
  31. ;             for the box walls when the keyword SOLID_WALLS
  32. ;            is set.
  33. ;
  34. ;    BACKGROUND:    The background color of the plot or the color
  35. ;            of the Grid and Plot data when the SOLID_WALLS
  36. ;            keyword is set.
  37. ;
  38. ;    XY_PLANE:    Setting this keyword will cause the X and Y values
  39. ;            of the data to be plotted on the Z=0 axis plane.
  40. ;
  41. ;    XZ_PLANE:    Setting this keyword will cause the X and Z values
  42. ;            of the data to be plotted on the Y=Ymax axis plane.
  43. ;
  44. ;    YZ_PLANE:    Setting this keyword will cause the Y and Z values
  45. ;            of the data to be plotted on the X=Xmax axis plane.
  46. ;
  47. ;    SOLID_WALLS:    Setting this keyword causes the axis "walls" of 
  48. ;            the plot box to be filled with the value of COLOR.
  49. ;
  50. ;    PSYM:        The plotting symbol that the data is draw with.
  51. ;
  52. ;    GRIDSTYLE:    Set this keyword to the linestyle that will be 
  53. ;            used in drawing the gridlines.
  54. ;
  55. ;    TITLE:        Set this keyword to the Main plot title
  56. ;    
  57. ;    XTITLE:        Set this keyword to the X axis title.
  58. ;
  59. ;    YTITLE:        Set this keyword to the Y axis title.
  60. ;
  61. ;    ZTITLE:        Set this keyword to the Z axis title.
  62. ;
  63. ;     SUBTITLE:    Set this keyword to the Sub-Title 
  64. ;
  65. ;    LINESTYLE:    The linestyle used to plot the data.
  66. ;
  67. ;    XYSTYLE:    The linesytle used to draw the plot in the XY plane.
  68. ;            If this keyword is not set, the value of LINESTYLE
  69. ;            is used.
  70. ;
  71. ;    XZSTYLE:    The linesytle used to draw the plot in the XZ plane.
  72. ;            If this keyword is not set, the value of LINESTYLE
  73. ;            is used.
  74. ;
  75. ;    YZSTYLE:    The linesytle used to draw the plot in the YZ plane.
  76. ;            If this keyword is not set, the value of LINESTYLE
  77. ;            is used.
  78. ;
  79. ;    Surface         All other keywords available to SURFACE are also
  80. ;    Keywords:    used by this procedure.
  81. ;
  82. ; OUTPUTS:
  83. ;    None.
  84. ;
  85. ; OPTIONAL OUTPUTS:
  86. ;    None.
  87. ;
  88. ; COMMON BLOCKS:
  89. ;    None.
  90. ;
  91. ; SIDE EFFECTS:
  92. ;    Plotting on the current device is performed.
  93. ;
  94. ; RESTRICTIONS:
  95. ;    None.
  96. ;
  97. ; PROCEDURE:
  98. ;    Straightforward.  Unrecognized keywords are passed to the SURFACE
  99. ;    procedure.  
  100. ;
  101. ; EXAMPLE:
  102. ;       Create some data that can be passed to Plot_3dbox
  103. ;
  104. ;       x = Replicate(5., 10)
  105. ;       x1 = cos(findgen(36)*10.*!dtor)*2.+5.     
  106. ;       x=[x,x1,x]     
  107. ;       y = findgen(56)     
  108. ;       z = Replicate(5., 10)
  109. ;       z1 =sin(findgen(36)*10.*!dtor)*2.+5.     
  110. ;       z=[z,z1,z]     
  111. ;
  112. ;     ; Plot this data in a "plot box" 
  113. ;
  114. ;       Plot_3dbox, X, Y, Z, /XY_PLANE, /YZ_PLANE, /XZ_PLANE, $
  115. ;                 /SOLID_WALLS, GRIDSTYLE=1, XYSTYLE=3, XZSTYLE=4, $
  116. ;                 YZSTYLE=5, AZ=40, TITLE="Example Plot Box",      $
  117. ;                 Xtitle="X Coodinate", Ytitle="Y Coodinate",      $
  118. ;                 Ztitle="Z Coodinate", SubTitle="Sub Title",      $
  119. ;                 /YSTYLE, ZRANGE=[0,10], XRANGE=[0,10],Charsize=1.6
  120. ;
  121. ;     ; Then to plot symbols on the locations of the above plot
  122. ;
  123. ;       plots, X, Y, Z, /T3D, PSYM=4, COLOR=!p.background
  124. ;
  125. ; MODIFICATION HISTORY:
  126. ;       6/94   KDB, RSI   - Initial Coding and Testing
  127. ;
  128. ;-
  129.  
  130. PRO Plot_3dbox, X, Y, Z, COLOR=COLOR, BACKGROUND=BACKGROUND,        $  
  131.                     XY_PLANE=XY_PLANE, YZ_PLANE=YZ_PLANE,        $  
  132.                     XZ_PLANE=XZ_PLANE, SOLID_WALLS=SOLID_WALLS,  $  
  133.                     PSYM=PSYM, GRIDSTYLE=GRIDSTYLE, TITLE=TITLE, $
  134.             XTITLE=XTITLE, YTITLE=YTITLE, ZTITLE=ZTITLE, $
  135.             SUBTITLE=SUBTITLE, LINESTYLE=LINESTYLE,      $
  136.                     XYSTYLE=XYSTYLE, YZSTYLE=YZSTYLE, XZSTYLE=XZSTYLE, $
  137.                     _EXTRA=e       
  138.  
  139. ;  Set up simple error handling
  140.        
  141.    On_ERROR, 2
  142.  
  143. ;  Lets make sure that all arrays are the same size     
  144.        
  145.    Xcnt = N_Elements(X)      
  146.    Ycnt = N_Elements(Y)     
  147.    Zcnt = N_Elements(Z)     
  148.      
  149.    if (Xcnt ne Ycnt) or (Xcnt ne Zcnt) then $
  150.           Message, "X, Y and Z arrays must have same number of elements "      
  151.      
  152. ;  Check the values of the keywords  
  153.      
  154.    if(N_Elements(PSYM)  eq 0)then      PSYM = 0  
  155.    if(N_Elements(COLOR) eq 0)then      COLOR = !P.COLOR  
  156.    if(N_Elements(BACKGROUND) eq 0)then BACKGROUND = !P.BACKGROUND  
  157.    if(N_Elements(GRIDSTYLE) eq 0)then  GRIDSTYLE = 1  
  158.    if(N_Elements(LINESTYLE) eq 0)then  LINESTYLE = 0  
  159.    if(N_Elements(XYSTYLE) eq 0)then    XYSTYLE = LINESTYLE  
  160.    if(N_Elements(XZSTYLE) eq 0)then    XZSTYLE = LINESTYLE
  161.    if(N_Elements(YZSTYLE) eq 0)then    YZSTYLE = LINESTYLE
  162.  
  163.    if(not KeyWord_Set(TITLE))then      TITLE=''
  164.    if(not KeyWord_Set(SUBTITLE))then   SUBTITLE=''
  165.    if(not KeyWord_Set(XTITLE))then     XTITLE=''
  166.    if(not KeyWord_Set(YTITLE))then     YTITLE=''
  167.    if(not KeyWord_Set(ZTITLE))then     ZTITLE=''
  168.    if(not KeyWord_Set(ZRANGE))then     ZRANGE=[Min(Z, MAX=zmax), zmax]
  169.  
  170. ;  Use SURFACE to set up the coordinates system, handle titles ect...     
  171.      
  172.    Surface, FltArr(Xcnt,Xcnt), X, Y, /NODATA, /SAVE, TICKLEN=1,        $ 
  173.       COLOR=COLOR, XGRIDSTYLE=GRIDSTYLE, YGRIDSTYLE=GRIDSTYLE,         $ 
  174.       ZGRIDSTYLE=GRIDSTYLE, BACKGROUND=BACKGROUND, XTICK_GET=xt,       $ 
  175.       YTICK_GET=yt, ZTICK_GET=zt,ZRANGE=ZRANGE, SUBTITLE=SUBTITLE,     $
  176.       TITLE=TITLE, YTITLE=YTITLE, ZTITLE=ZTITLE, XTITLE=XTITLE, _EXTRA=e    
  177.  
  178.    name = replicate(' ' ,30)   ; Make up null tick names  
  179.      
  180. ;  See if the user wants to have "Solid" box walls  
  181.   
  182.    if(KeyWord_Set(SOLID_WALLS))then BEGIN  
  183.   
  184.    ;  Using the values of Crange, fill in the box walls with the value  
  185.    ;  of color  
  186.   
  187.       PolyFill, [!X.Crange[0], !X.Crange, !X.Crange[1]],  $;bottom  
  188.                 [!Y.Crange, !Y.Crange[1], !Y.Crange[0]],  $  
  189.                 Replicate(!Z.Crange[0], 4), /T3D, COLOR=COLOR  
  190.       PolyFill, [!X.Crange[0], !X.Crange, !X.Crange[1]],  $ ; Back  
  191.                 Replicate(!Y.Crange[1],4),                $  
  192.                 [!Z.Crange, !Z.Crange[1], !Z.Crange[0]],  $  
  193.                 /T3D, COLOR=COLOR  
  194.       PolyFill, Replicate(!X.Crange[1],4), /T3D, COLOR=COLOR, $ ;side  
  195.                 [!Y.Crange, !Y.Crange[1], !Y.Crange[0]],  $  
  196.                 [!Z.Crange[0], !Z.Crange, !Z.Crange[1]]  
  197.  
  198.    ;  Now Replot the surface data  
  199.   
  200.       COLOR=BACKGROUND  ; reverse colors 
  201.  
  202.       Surface, FltArr(Xcnt,Xcnt), X, Y, /NODATA, /SAVE, TICKLEN=1,       $ 
  203.               /NOERASE, COLOR=COLOR, XTICKNAME=name, YTICKNAME=name,     $  
  204.               ZTICKNAME=name, XGRIDSTYLE=GRIDSTYLE, YGRIDSTYLE=GRIDSTYLE,$  
  205.               ZGRIDSTYLE=GRIDSTYLE, ZRANGE=ZRANGE, _EXTRA=e     
  206.  
  207.    ENDif  ;if solid walls set.  
  208.    
  209. ;  Now complete the drawing of the axis box     
  210.      
  211.    Axis, !X.Crange[1], !Y.Crange[1], !Z.Crange[1], /YAXIS, /T3D,    $ 
  212.          YTICKNAME = name, COLOR=COLOR, YTICKLEN=0     
  213.    Axis, !X.Crange[1], !Y.Crange[0], !Z.Crange[0], ZAXIS=-1, /T3D,  $ 
  214.          ZTICKNAME = name, COLOR=COLOR, ZTICKLEN=0     
  215.    Axis, !X.Crange[0], !Y.Crange[1], !Z.Crange[0], /XAXIS, /T3D,    $ 
  216.          XTICKNAME = name, COLOR=COLOR, XTICKLEN=0     
  217.    Axis, !X.Crange[0], !Y.Crange[1], !Z.Crange[1], /XAXIS, /T3D,    $  
  218.          XTICKNAME = name, COLOR=COLOR, XTICKLEN=0     
  219.    Axis, !X.Crange[1], !Y.Crange[1], !Z.Crange[0], ZAXIS=-1, /T3D,  $ 
  220.          ZTICKNAME = name, COLOR=COLOR, ZTICKLEN=0     
  221.    Axis, !X.Crange[1], !Y.Crange[0], !Z.Crange[1], YAXIS=-1, /T3D,  $ 
  222.          YTICKNAME = name, COLOR=COLOR, YTICKLEN=0     
  223.    Axis, !X.Crange[1], !Y.Crange[0], !Z.Crange[0], /YAXIS, /T3D,    $ 
  224.          YTICKNAME = name, COLOR=COLOR, YTICKLEN=0     
  225.  
  226. ; now plot the data     
  227.      
  228.   Plots, X, Y, Z, /T3D , PSYM=PSYM, COLOR=COLOR ,LINESTYLE=LINESTYLE, $
  229.                          _EXTRA=e
  230.  
  231. ; And now plot the data along the walls of the box if requested
  232.  
  233.   if(KeyWord_Set(XY_PLANE))then $     
  234.       Plots, X, Y, Replicate(!Z.Crange[0], Zcnt), /T3D, COLOR=COLOR, $
  235.                LINESTYLE=XYSTYLE
  236.   if(KeyWord_Set(YZ_PLANE))then $     
  237.       Plots, Replicate(!X.Crange[1], Xcnt), Y, Z, /T3D, COLOR=COLOR, $
  238.                LINESTYLE=YZSTYLE
  239.   if(KeyWord_Set(XZ_PLANE))then $     
  240.       Plots, X, Replicate(!Y.Crange[1], Ycnt), Z, /T3D, COLOR=COLOR, $
  241.                LINESTYLE=XZSTYLE
  242.  
  243. ; now draw the grid lines on the plot that were not drawn by surface     
  244.      
  245.   for i=0, N_Elements(yt)-1 do $     
  246.         Plots, [!X.Crange[1],!X.Crange[1]], [yt[i],yt[i]], !Z.Crange, /T3D, $  
  247.                LINESTYLE=GRIDSTYLE, COLOR=COLOR  
  248.   for i=0, N_Elements(zt)-1 do $     
  249.         Plots, [!X.Crange[1],!X.Crange[1]], !Y.Crange, [zt[i],zt[i]], /T3D, $  
  250.                LINESTYLE=GRIDSTYLE, COLOR=COLOR  
  251.   for i=0, N_Elements(xt)-1 do $     
  252.         Plots, [xt[i],xt[i]], [!Y.Crange[1],!Y.Crange[1]], !Z.Crange, /T3D, $  
  253.                LINESTYLE=gridstyle, COLOR=COLOR  
  254.  
  255. END
  256.  
  257.  
  258.